明凯博客

关注网站技术,一个特立独行的程序员

Asp中的类的使用方法详解

严格地说,ASP 并不是一门编程语言,所以不存在类这一概念,我们这里说 ASP 类是指 ASP 的编程语言 VBScript 在 ASP 里应用时的类。

ASP 类比较简单,它不具有真正意义类的继承、重载等特性,尽管如此,它仍然是非常有用的,它降低了我们编程的复杂度,使我们的程序模块更加合理。

ASP 类比较简单,它不具有真正意义类的继承、重载等特性。

它支持以下内容:

公有成员变量、私有成员变量、属性
公有成员函数、私有成员函数
构造函数、析构函数

创建和使用一个最简单的ASP类一些初学者不理解类和对象的区别,打个比方,类好比是图纸,对象好比是根据图纸制作出的实物。

首先ASP的类是由事件和方法(它们就是构成类的成员了)构成的,在 Class 块中,成员通过相应的声明语句被声明为 Private(私有成员,只能在类内部调用) 或 Public(公有成员,可以在类内外部调用) 。

被声明为 Private 的将只在 Class 块内是可见的。被声明为 Public 不仅在 Class 块的内部是可见的,对 Class 块之外的代码也是可见的。

没有使用 Private 或 Public 明确声明的被默认为 Public。在类的块内部被声明为 Public 的过程(Sub 或 Function)将成为类的方法。

Public 变量将成为类的属性,同使用 Property Get、Property Let 和 Property Set 显式声明的属性一样。类的缺省属性和方法是在它们的声明部分用 Default 关键字指定的。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
 
'----------------------------ASP中类的使用---------------------------------
 
Class ALoaferClass 
 
'---- 声明(声明就是定义)CaboClass类的类内部(私有)变量
 
'---- 声明时一般将变量定义成[Private]私有,通过属性读写器将变量[Public] 公开
 
Private strAuthor 
Private strVersion 
Private strExample 
 
'---------------------------定义类的事件-------------------------------------
 
'---Class_Initialize()是类的初始化事件,类被调用,首先会触发该部分的执行,一般用来初始化默认值.
 
Private Sub Class_Initialize() 
    strAuthor = "MK" 
    strVersion = "v1.0" 
    Response.Write("<br />ALoafer Class开始了<br />")
End Sub 
 
'----Class_Terminate()是类的结束事件,退出该类,就会触发该事件。
 
Private Sub Class_Terminate() 
    Response.Write("<br />ALoafer Class结束了<br />")
End Sub 
 
'---------------------------用户自己定义的方法-------------------------------
 
'----该方法返回一个版权信息 
 
Public Sub Information() 
    Response.Write("<br />Coding By <a href='www.aimks.com'>明凯博客</a>")
End Sub 
 
'---------------------------定义类的输出属性--------------------------------
'----定类的属性,该属性是让用户初始化strExapmle变量 
 
Public Property Let SetExapmle(ByVal strVar) 
    strExapmle = strVar 
End Property 
 
'----定义类的属性,该属性是返回一个版本号 
 
Public Property Get Version 
    Version = strVersion 
End Property 
 
'----定义类的属性,该属性是返回该类的作者号 
 
Public Property Get Author 
    Author = strAuthor 
End Property 
 
'----定义类的属性,该属性是返回自定义值
 
Public Property Get Exapmle 
    Exapmle = strExapmle 
End Property 
 
End Class 
 
 
 
'---------------------------ASP类的调用-------------------------------- 
'---- 使用 set new 创建对象,由于不是服务器组件,所以不能用 server.CreateObject 创建
 
Dim oneNewClass 
Set oneNewClass = New ALoaferClass  
Response.Write("作者: "& oneNewClass.Author &" <br />")
Response.Write("版本: "& oneNewClass.Version &" <br />")
oneNewClass.SetExapmle = "这是一个简单类的例子" 
Response.Write("用户自定义:" & oneNewClass.Exapmle &" <br />")
Response.Write(oneNewClass.Information)
Set oneNewClass = Nothing   '释放对象

, , , ,

相关文章

2 条评论 “Asp中的类的使用方法详解

发表评论

电子邮件地址不会被公开。 必填项已用*标注